;---------------------------------------------
; Close Nag-Screen of Total Commander
; Copyright (C) ManHunter / PCL
; http://www.manhunter.ru - Так-то очень полезный ресурс
;---------------------------------------------

format PE GUI 4.0
entry start

include 'win32a.inc'

section '.data' data readable writeable

szNag   db 'TNASTYNAGSCREEN',0

button   db '&',0,0
buff     rb 3

nag      dd ?

;---------------------------------------------------------

section '.code' code readable executable

start:
          ; Найти наг-скрин Total Commander
          invoke  FindWindow,szNag,NULL
          or      eax,eax
          jz      loc_exit

          ; Сохранить хэндл окна
          mov     [nag],eax

          ; Найти нужный номер кнопки
          invoke  EnumChildWindows,[nag],FindNastyNumber,NULL

          ; Кликнуть на нужную кнопку
          invoke  EnumChildWindows,[nag],ClickNastyButton,NULL

loc_exit:
          invoke  ExitProcess,0

; Рекурсивная функция перебора всех дочерних элементов
proc FindNastyNumber hwnd:dword,lParam:dword
          mov     [buff],0
          ; Прочитать текст дочернего элемента
          invoke  GetWindowText,[hwnd],buff,3
          cmp     eax,1
          jne     @f
          ; Сохранить текст кнопки
          invoke  lstrcpy,button+1,buff
@@:
          invoke  EnumChildWindows,[hwnd],FindNastyNumber,NULL

          mov     eax,1
          ret
endp

; Рекурсивная функция перебора всех дочерних элементов
proc ClickNastyButton hwnd:dword,lParam:dword
          mov     [buff],0
          ; Прочитать текст дочернего элемента
          invoke  GetWindowText,[hwnd],buff,3
          ; Это текст искомой кнопки?
          invoke  lstrcmp,buff,button
          or      eax,eax
          jnz     @f

          ; Эмулировать нажатие на кнопку
          invoke  SendMessage,[hwnd],WM_SETFOCUS,NULL,NULL
          invoke  SendMessage,[hwnd],WM_LBUTTONDOWN,MK_LBUTTON,NULL
          invoke  SendMessage,[hwnd],WM_LBUTTONUP,MK_LBUTTON,NULL
@@:
          invoke  EnumChildWindows,[hwnd],ClickNastyButton,NULL

          mov     eax,1
          ret
endp

;---------------------------------------------------------

section '.idata' import data readable writeable

    library kernel32,'kernel32.dll',\
            user32,'user32.dll',\
            shell32,'shell32.dll'

    include 'api\kernel32.inc'
    include 'api\user32.inc'
    include 'api\shell32.inc'